// PC-Access Auto Update Server Script File      10-08-97
//
// This script performs the login function to initiate an
// automatic update of PC Access.
//
// ******************************************************

label START;

keyboard OFF;
autozmodem OFF;

if @CONNECT_TYPE == "TELNET" then goto TCP_LOGIN;
if @CONNECT_TYPE == "RLOGIN" then goto TCP_LOGIN;

wait 10000 for "<RETURN> to begin Login Session" timeout goto TIMEOUT;
send "^M";

label TCP_LOGIN;
wait 10000 for "ogin:" timeout goto LOGINTIMEOUT;
send "pcawupdate^M";
goto LOGINOKAY;

label LOGINTIMEOUT;
send "pcawupdate^M";

label LOGINOKAY;
wait 20000 for "assword:" timeout goto TIMEOUT;
send "omnikey95^M";
wait 25000 for "version:" timeout goto TIMEOUT;
send "^!PCAWIN_VERSION^M";
wait 25000 for "build:" timeout goto TIMEOUT;
send "^!PCAWIN_BUILD^M";

label WAIT;

on "sending..." goto UPDATE;
on "version ok" goto NO_UPDATE;
delay 25000;
goto TIMEOUT;

label UPDATE;

delay 1500;
download ".\" using ZMODEM abort FAILED;
messagebox title "Transfer Complete" text "You must restart PC Access for Windows to install the update.";
exit APPLICATION;

label FAILED;

delete "PCAWUPDT.EXE";
hangup;
messagebox title "Download Failure" text "The update was cancelled or could not continue. Try again later.";
exit SESSION;

label NO_UPDATE;

hangup;
messagebox title "No Update Needed" text "Your version of PC Access for Windows is up to date.";
exit SESSION;

label TIMEOUT;                      // Timeout occurred, notify program and

hangup;
messagebox title "Update Failed!" text "Timeout waiting for data.";
exit SESSION;